تخطى إلى المحتوى
Home » المقالات » دليل المبتدئين لـ Salesforce Apex: مقدمة عن الـ Collections (Lists وSets وMaps)

دليل المبتدئين لـ Salesforce Apex: مقدمة عن الـ Collections (Lists وSets وMaps)

أهلاً يا coding crew! في البوست ده هتكلم عن واحدة من أقوى الحاجات في البرمجة على Salesforce: الـ Collections. زي ما إنتو عارفين، الـ collections بنستخدمها عشان نخزن مجموعات من الداتا اللي ليها علاقة ببعض، وليها تلات أنواع: Lists وSets وMaps. هنعدي في البوست ده على مقدمة للـ collections دي وأنواعها في Salesforce Apex. سواء إنتو جداد على البرمجة في Salesforce أو عايزين توسعوا معلوماتكم، إنتو في المكان الصح! ومتقلقوش لو لسه مش عارفين يعني إيه collections، أنا هنا عشان أمشي معاكم خطوة خطوة. قبل ما نبدأ، أنصحكم تبصوا على البوست اللي قبله ‘Beginner’s Guide to Salesforce: Primitive Data Types and Methods‘ (بالإنجليزي)، اللي بيشرح الـ variables والـ primitive data types. ده أساس مهم جداً عشان تفهموا الـ collections في Salesforce Apex.

ولو إنتو لسه جداد على عالم الـ Salesforce development، أنصحكم تبدأوا بالبوست ده الأول “Essential Salesforce Developer Vocabulary for Beginners” (بالإنجليزي).

الـ Lists: أول نوع من الـ Collections في Salesforce Apex

الـ Apex List هي collection فيها كذا item، زي بالظبط الـ to-do list اللي بتضيفوا فيها مهام جديدة، وتشيلوا اللي خلصت، وترتبوا الأولويات حسب ما تحبوا تخلصوها. ترتيب الـ items في الـ List مهم، وممكن تغيروه لو رتبتوها من جديد.

صورة بتوضح أول نوع من الـ Collections في Salesforce Apex وهو الـ List، كـ array ليها index والعناصر مترتبة ورا بعض

كل item في الـ Apex List ليه Index مميز، اعتبروه العنوان بتاعه. ده بيسهل إنكم تجيبوا item معين من الـ List باستخدام الـ Index بتاعه. وعلى عكس الـ Sets، الـ Lists بتحافظ على ترتيب العناصر وبتسمح بالتكرار (duplicates).

الـ Syntax

الـ syntax اللي تحت بنستخدمه عشان نعمل declare وinitialize لـ List فاضية، ونضيف items بالـ method اللي اسمها “add“، ونجيب item من الـ List بالـ method اللي اسمها “get“:

//Declaring and initializing an empty List
List<DataType> listName = new List<DataType>();

//Adding items to the list
listName.add(ValueSameDataType);

//Retrieving Items from the list
DataType variableName = listName.get(ItemIndex);
  • List<DataType>: بتحدد نوع الـ List اللي بتعملوها.
  • DataType: بيحدد الـ data type بتاع العناصر اللي الـ List تقدر تشيلها.
  • listName: الاسم اللي بتدوه للـ List variable، وبيه هتشاوروا على الـ List بعد كده في الكود.
  • new List(): ده constructor بيعمل instance جديدة من الـ List.
  • add(): built-in method بنستخدمها عشان نضيف items للـ List.
  • ValueSameDataType: قيمة من نفس الـ DataType بتاع الـ List.
  • variableName: variable من نفس الـ DataType بتاع الـ List، هيشيل القيمة اللي عايزين نجيبها من الـ list.
  • get(): built-in method بنستخدمها عشان نجيب item من الـ list بالـ index بتاعه. والعد بيبدأ من 0.
  • ItemIndex: رقم integer للـ index بتاع الـ item اللي عايزين نجيبه. مثلاً في الـ list اللي فوق، “Drink Coffee” موجودة في index رقم 4.

وممكن كمان تعملوا initialize للـ List بالقيم في سطر واحد:

List<DataType> listName = new List<DataType>{value1, value2, value3, value4};

value1 وvalue2 وvalue3 وvalue4 قيم من نفس الـ data type اللي محدد في DataType.

تعالوا نشوف الأمثلة دي:

//empty String list
List<String> lstDayNames= new List<String>(); 
lstDayNames.add('Monday'); //add value to the list

//List of Strings with three values
List<String> lstMonthNames = new List<String>{'February','April','May','February'};
lstMonthNames.add('June'); //add extra month

//Empty list of Accounts
List<Account> lstAccounts = new List<Account>();

//List of Integers with 2 values in it
List<Integer> lstNumbers = new List<Integer>{2,3};
lstNumbers.add(11); //add extra Integer value

//Retrieving items from the lists we defined
System.debug('Check Day Name: '+ lstDayNames.get(0));
System.debug('Check Month Name: '+ lstMonthNames.get(2));
System.debug('Check Number Value: '+lstNumbers.get(1));
صورة من الـ Salesforce Developer Console بتعرض output لـ List، العناصر والـ index بتاع كل واحد
صورة من الـ log في الـ Developer Console.

أهم الـ List Methods

اتكلمنا قبل كده عن أشهر اتنين List methods، “add()” و”get()”. بس فيه methods تانية كتير مفيدة تقدروا تستخدموها مع الـ Lists! في الجزء ده هوريكم أمثلة على شوية منها. وافتكروا، لو عايزين تعرفوا أكتر عن كل الـ List Methods، بصوا على الـ resources.

اسم الـ Methodاستخدامهامثال
sort()بترتب الـ items في الـ list ترتيب تصاعديList<Integer> lstScores=new List<Integer>{4,1,22,10};
System.debug(‘List Before Sorting: ‘+lstScores);
lstScores.sort();
System.debug(‘List After Sorting: ‘+lstScores);

الـ Output في الـ Developer Console:
List Before Sorting: (4, 1, 22, 10)
List After Sorting: (1, 4, 10, 22)
size()بترجع عدد الـ items اللي في الـ listList<Integer> lstScores=new List<Integer>{4,1,22,10};
System.debug(‘List Size: ‘+lstScores.size());

الـ Output في الـ Developer Console:
List Size: 4
isEmpty()بترجع true لو الـ list فاضية، وغير كده بترجع falseList<Integer> lstScores=new List<Integer>();
System.debug(‘Check if empty1: ‘+lstScores.isEmpty());
lstScores.add(4);
System.debug(‘Check if empty2: ‘+lstScores.isEmpty());

الـ Output في الـ Developer Console:
Check if empty1: true
Check if empty2: false
contains()بترجع true لو الـ list فيها الـ item اللي بدور عليه، وغير كده بترجع falseList<Integer> lstScores=new List<Integer>{4,1,22,10};
System.debug(‘List Contains 4: ‘+lstScores.contains(4));
System.debug(‘List Contains 100: ‘+lstScores.contains(100));

الـ Output في الـ Developer Console:
List Contains 4: true
List Contains 100: false
جدول بعينة من الـ List Methods

إزاي نعمل Loop على List

عشان تلفوا على list في Salesforce، تقدروا تستخدموا for loop، وهنشرحها بالتفصيل في بوست تاني فخليكم متابعين!

ده مثال:

//Initialize a list of String and values to it
List<String> lstFruitNames = new List<String>{'Orange', 'Watermelon', 'Cherry'};

//loop over the list of Strings for the fruit names 
for(String strFruitName : lstFruitNames){
    System.debug('Fruit Name: '+strFruitName);
}

الـ loop variable اللي اسمه “strFruitName” بياخد قيمة كل item في الـ list، وبنستخدم System.debug() عشان نطبع كل string.

صورة من الـ Salesforce Developer Console بتعرض نتيجة الـ loop على List وطباعة كل عنصر
صورة من الـ log في الـ Developer Console.

الـ Sets: الـ Collection اللي بتشيل قيم مش متكررة في Salesforce Apex

الـ Sets نوع تاني من الـ collections في Salesforce، بتخزن مجموعة داتا ليها علاقة ببعض، زي الـ Lists بالظبط. بس الفرق الأساسي إن الـ sets مش بتخزن الداتا بترتيب معين، ومش بتسمح بالتكرار.

تعالوا نشبّه الـ sets بالفاتورة اللي بتاخدوها بعد ما تخلصوا شوبينج السوبر ماركت ويتعمل scan لكل الحاجات اللي في العربية:

  • تخيلوا إنكم بتشتروا حاجات من السوبر ماركت وبتحطوا شوية حاجات في العربية.
  • العربية ممكن يبقى فيها حاجات متكررة، زي مثلاً إنكم تشتروا علبتين شوربة من نفس النوع.
  • لما تحاسبوا، الكاشير هيعمل scan لكل item مرة واحدة بس، حتى المتكرر.
  • الفاتورة هتعرض كل item مرة واحدة بس، مهما كان عدد المرات اللي اتكرر فيها في العربية.

وده شبه الطريقة اللي الـ sets بتشتغل بيها: كل item بيظهر مرة واحدة بس في الـ set، حتى لو ضفتوا نفس القيمة أكتر من مرة.

صورة عربية سوبر ماركت مليانة حاجات، كمثال من الحياة الحقيقية على الـ Set في Salesforce Apex
صورة فاتورة فيها الحاجات اللي اتشرت من غير تكرار، بتمثل فكرة الـ Set في Salesforce Apex

الـ Set اللي بتمثل الحاجات اللي في الفاتورة اللي فوق هتبقى كده:

//Define Item Set as Set of String 
Set<String> setItems = new Set<String>{'Cheese','Chicken Soup','Pizza','Bread','Chicken'};

الـ Syntax

الـ syntax اللي جاي بنستخدمه عشان نعمل declare وinitialize لـ Set فاضية ونضيف items بالـ method اللي اسمها ‘add’. مينفعش نجيب item بالـ index زي ما عملنا مع الـ List، لأن الـ Sets مش مترتبة، ومفيش item ليه index (عنوان).

Set<DataType> setName = new Set<DataType>(); //initializing an empty set
setName.add(ValueSameDataType); //adding items in the set
  • Set<DataType>: بتحدد نوع الـ Set اللي بتعملوها.
  • DataType: بيحدد الـ data type بتاع العناصر اللي الـ Set تقدر تشيلها.
  • setName: الاسم اللي بتدوه للـ Set variable، وبيه هتشاوروا على الـ Set بعد كده في الكود.
  • new Set(): ده constructor بيعمل instance جديدة من الـ Set.
  • ValueSameDataType: قيمة من نفس الـ DataType بتاع الـ Set.

وممكن كمان تعملوا initialize للـ Set بالقيم في سطر واحد، زي ما عملنا في مثال الفاتورة فوق:

//Initializing a set and add to it four values in the same line of code
Set<DataType> setName = new Set<DataType>{value1, value2, value3, value4};

value1 وvalue2 وvalue3 وvalue4 قيم من نفس الـ data type اللي محدد في DataType.

تعالوا نشوف الأمثلة دي:

Set<String> setWeekDays = new Set<String>(); //Declare and initialize an empty Set 
setWeekDays.add('Monday'); //add values to the set 
setWeekDays.add('Monday'); //add duplicate value to the set (No error and it would be ignored)
setWeekDays.add('Tuesday'); //add values to the set 
System.debug('Check Days : '+setWeekDays);

//Declare and initialize a set of integers
Set<Integer> setScores = new Set<Integer>{33,27,21,25};
System.debug('Check Scores : '+setScores);
صورة من الـ Salesforce Developer Console بتعرض output لـ Set، العناصر من غير تكرار ومن غير ترتيب
صورة من الـ log في الـ Developer Console.

أهم الـ Set Methods

شفنا بسرعة وإحنا بنتعلم الـ syntax بتاع الـ Sets أهم method هتستخدموها كتير وهي “add()”. فيه methods تانية تقدروا تستخدموها مع الـ Set، هوريكم عينة منها هنا، بس بصوا على الـ resources عشان تعرفوا أكتر عن باقي الـ Set Methods.

اسم الـ Methodاستخدامهامثال
contains()بترجع true لو الـ Set فيها الـ item اللي بدور عليه، وغير كده بترجع falseSet<Integer> setScores=new Set<Integer>{20,11,9};
System.debug(‘Set Contains 25: ‘+setScores.contains(25));
System.debug(‘Set Contains 11: ‘+setScores.contains(11));

الـ Output في الـ Developer Console:
Set Contains 25: false
Set Contains 11: true
isEmpty()بترجع true لو الـ Set فاضية، وغير كده بترجع false.Set<Integer> setScores=new Set<Integer>();
System.debug(‘Check isEmpty1 : ‘+setScores.isEmpty());
setScores.add(21);
System.debug(‘Check isEmpty2 : ‘+setScores.isEmpty());

الـ Output في الـ Developer Console:
Check isEmpty1 : true
Check isEmpty2 : false
size()بترجع عدد الـ items اللي في الـ set.Set<Integer> setScores=new Set<Integer>{20,11,19};
System.debug(‘Check Set Size1: ‘ +setScores.size());

//Add duplicate Value
setScores.add(20);
System.debug(‘Check Set Size2: ‘ +setScores.size());

//Add a new value to the Set
setScores.add(25);
System.debug(‘Check Set Size3: ‘ +setScores.size());

الـ Output في الـ Developer Console:
Check Set Size1: 3
Check Set Size2: 3
Check Set Size3: 4

ملحوظة: لما ضفنا item متكرر في الـ set مطلعش error، بس كمان متضافش للـ set، وعشان كده size1 وsize2 زي بعض
addAll(fromList)الـ method دي بتضيف عناصر الـ List للـ Set لو مش موجودة فيها أصلاً.

الـ method هتعدل الـ Set بتاعتكم، وهترجع true لو حصل فيها تعديل.
Set<String> setUniqueValues = new Set<String>();

List<String> lstValues1 = new List<String>();
lstValues1.add(‘Sally’);
lstValues1.add(‘Testing’);

List<String> lstValues2 = new List<String>();
lstValues2.add(‘Checking’);
lstValues2.add(‘Sally’);

List<String> lstValues3 = new List<String>();
lstValues3.add(‘Checking’);
lstValues3.add(‘Sally’);

Boolean isUpdated1=setUniqueValues.addAll(lstValues1);
Boolean isUpdated2=setUniqueValues.addAll(lstValues2);
Boolean isUpdated3=setUniqueValues.addAll(lstValues3);

System.debug(‘Check isUpdated1 : ‘+isUpdated1);
System.debug(‘Check isUpdated2 : ‘+isUpdated2);
System.debug(‘Check isUpdated3 : ‘+isUpdated3);
System.debug(‘Check setUniqueValues : ‘+setUniqueValues);

الـ Output في الـ Developer Console:
Check isUpdated1 : true
Check isUpdated2 : true
Check isUpdated3 : false
Check setUniqueValues : {Checking, Sally, Testing}
جدول بعينة من الـ Set Methods

إزاي نعمل Loop على Set

عشان تلفوا على Set في Salesforce، تقدروا تستخدموا for loop، وهنشرحها بالتفصيل في بوست تاني فخليكم متابعين!

ده مثال:

//Initialize a Set of String and values to it
Set<String> setFruitNames = new Set<String>{'Orange', 'Watermelon', 'Cherry'};

//loop over the Set of Strings for the fruit names 
for(String strFruitName : setFruitNames){
    System.debug('Fruit Name Set Example: '+strFruitName);
}

الـ loop variable اللي اسمه “strFruitName” بياخد قيمة كل item في الـ Set، وبنستخدم System.debug() عشان نطبع كل string.

صورة من الـ Salesforce Developer Console بتعرض نتيجة الـ loop على Set وطباعة كل عنصر
صورة من الـ log في الـ Developer Console.

الـ Maps: الـ Collection اللي بتشيل Key-Value Pairs في Salesforce Apex

الـ Maps نوع تالت من الـ collections في Salesforce بتخزن مجموعة داتا ليها علاقة ببعض. زي الـ Lists والـ Sets، الـ Maps بتخليكم تخزنوا الداتا وتتعاملوا معاها، بس ليها مميزات خاصة بيها.

الفرق الأساسي بين الـ Maps وباقي أنواع الـ collections إن الـ maps بتخزن الداتا على شكل key-value pairs. يعني تقدروا تربطوا value بـ key معين، وبعدين تستخدموا الـ key ده عشان تجيبوا الـ value بتاعته.

تعالوا نستخدم نفس فاتورة السوبر ماركت اللي اتكلمنا عنها في الـ Sets عشان نفهم استخدام مختلف للـ Maps.

صورة فاتورة فيها الحاجات والكمية بتاعة كل واحدة، بتمثل فكرة الـ Map في Salesforce Apex كـ key-value pairs

شفنا إزاي استخدمنا الـ Set عشان نجيب لستة الحاجات اللي اشتريناها. طب لو عايزين نجيب الحاجات اللي اشتريناها والكمية بتاعة كل واحدة؟ ده مش هينفع بالـ Set، لكن ينفع بالـ Map لأنها بتخزن key-value pairs، كده:

Map<String,Integer> mapItemsQuantity = new Map<String,Integer>();
mapItemsQuantity.put('Cheese',1);
mapItemsQuantity.put('Chicken Soup',3);
mapItemsQuantity.put('Pizza',2);
mapItemsQuantity.put('Bread',1);
mapItemsQuantity.put('Chicken',1);

الـ Syntax

الـ syntax اللي جاي بنستخدمه عشان نعمل declare وinitialize لـ Map فاضية، ونضيف items بالـ method اللي اسمها ‘put‘، ونجيب item معين باستخدام الـ key بتاعه والـ method اللي اسمها ‘get‘.

//Initialize an empty map and specifying its key data type and value data type
Map<DataTypeOfKey, DataTypeOfValue> mapName = new Map<DataTypeOfKey, DataTypeOfValue>();

//syntax to put key-value pairs in the map
mapName.put(keySameType,ValueSameType); 

//retrieve a value from the map using its key
DataTypeOfValue retrievedValue = mapName.get(KeyValue);
  • Map<DataTypeOfKey,DataTypeOfValue>: بتحدد الـ data type بتاع الـ key والـ data type بتاع الـ value.
  • mapName: الاسم اللي بتدوه للـ Map variable، وبيه هتشاوروا على الـ Map بعد كده في الكود.
  • new Map(): ده constructor بيعمل instance جديدة من الـ Map، وهتبقى map فاضية.
  • put(): method بنستخدمها عشان نضيف key-value pair للـ map.
  • retrievedValue: اسم variable من نفس الـ data type بتاع الـ value.
  • get(): method بنستخدمها عشان نجيب value معينة من الـ map باستخدام الـ key بتاعها.

وممكن كمان تعملوا initialize للـ Map بالقيم في سطر واحد، كده:

Map<DataTypeOfKey, DataTypeOfValue> myMap = new Map<DataTypeOfKey, DataTypeOfValue>{
                                                  Key1 => Value1, 
                                                  Key2 => Value2};

تعالوا نشوف الأمثلة دي:

//Initialize an empty map with Key as String and value as number
Map<String,Integer> mapStudentScores=new Map<String,Integer>();

//Add key pair values
mapStudentScores.put('Sally',22);
mapStudentScores.put('Sarah',30);
mapStudentScores.put('Emilia',27);

//Test Getting the score of Sarah
System.debug('Sarah Score: '+mapStudentScores.get('Sarah'));

//Declare and Initialize a map and add key-value pairs at same line
Map<String,Integer> mapStudentAge=new Map<String,Integer>{
                                          'Daniel'=>12,
                                          'Andrew'=>11,
                                          'Mark'=>13};

//Test Getting the Age of Mark and printing it
System.debug('Mark Age: '+mapStudentAge.get('Mark'));
صورة من الـ Salesforce Developer Console بتعرض output لـ Map، والـ key-value pairs اللي فيها
صورة من الـ log في الـ Developer Console.

الـ keys في الـ Map مبتتكررش، فلو حاولتوا تضيفوا نفس الـ key أكتر من مرة بقيم مختلفة، آخر قيمة هي اللي هتتخزن.

/* declare and initialize the map where the day String value is the key and temperature
  Integer is the value */
Map<String,Integer> mapDaysTemperature = new Map<String,Integer>();
mapDaysTemperature.put('Monday',13);
mapDaysTemperature.put('Tuesday',15); 
mapDaysTemperature.put('Tuesday',30); //this is duplicate

System.debug('Tuesday Temperature : '+mapDaysTemperature.get('Tuesday'));
صورة من الـ Salesforce Developer Console بتوضح إن آخر قيمة لـ key متكرر بتمسح القيمة اللي قبلها في الـ Map
صورة من الـ log في الـ Developer Console.

أهم الـ Map Methods

شفنا بسرعة وإحنا بنتعلم الـ syntax بتاع الـ Maps اتنين methods مهمين هتستخدموهم كتير: “put()” و”get()”. فيه methods تانية تقدروا تستخدموها مع الـ Maps، هوريكم عينة منها هنا، بس بصوا على الـ resources عشان تعرفوا أكتر عن باقي الـ Map Methods.

اسم الـ Methodاستخدامهامثال
keySet()بترجع Set فيها كل الـ keys اللي في الـ MapMap<String,Integer> mapItems=new Map<String,Integer>();
mapItems.put(‘Cheese’,1);
mapItems.put(‘Chicken Soup’,3);
mapItems.put(‘Pizza’,2);
System.debug(‘Check Map Keys: ‘+mapItems.keySet());

الـ Output في الـ Developer Console:
Check Map Keys: {Cheese, Chicken Soup, Pizza}
values()بترجع List فيها الـ values اللي في الـ Map Map<String,Integer> mapItems=new Map<String,Integer>();
mapItems.put(‘Cheese’,1);
mapItems.put(‘Chicken Soup’,3);
mapItems.put(‘Pizza’,2);
mapItems.put(‘Butter’,2);
System.debug(‘Check Map Values: ‘+mapItems.values());

الـ Output في الـ Developer Console:
Check Map Values: (1, 3, 2, 2)
isEmpty()بترجع true لو الـ Map فاضية، وغير كده بترجع false.Map<String,Integer> mapItems=new Map<String,Integer>();
System.debug(‘Check isEmpty1: ‘+mapItems.isEmpty());
mapItems.put(‘Cheese’,1);
System.debug(‘Check isEmpty2: ‘+mapItems.isEmpty());

الـ Output في الـ Developer Console:
Check isEmpty1: true
Check isEmpty2: false
size()بترجع عدد الـ key-value pairs اللي في الـ map.Map<String,Integer> mapItems=new Map<String,Integer>();
System.debug(‘Check size1: ‘+mapItems.size());
mapItems.put(‘Cheese’,1);
mapItems.put(‘Butter’,2);
System.debug(‘Check size2: ‘+mapItems.size());

الـ Output في الـ Developer Console:
Check size1: 0
Check size2: 2
containsKey(key)بترجع true لو الـ map فيها key-value pair بالـ key اللي بندور عليهMap<String,Integer> mapItems=new Map<String,Integer>();
mapItems.put(‘Cheese’,1);
mapItems.put(‘Butter’,2);
System.debug(‘Check1: ‘+mapItems.containsKey(‘Cheese’));
System.debug(‘Check2: ‘+mapItems.containsKey(‘Milk’));

الـ Output في الـ Developer Console:
Check1: true
Check2: false
جدول بعينة من الـ Map Methods

إزاي نعمل Loop على Map

في Salesforce تقدروا تستخدموا for loop عشان تلفوا على الـ collections. هنشرح ده بتفصيل أكتر في بوست جاي، فخليكم متابعين!

لما نيجي نلف على Map في Salesforce، هي فيها key-value pairs، وفيه طريقتين نلف بيهم على القيم اللي فيها:

  1. طريقة إننا نلف على الـ keys، وبعدين نستخدم الـ method اللي اسمها ‘get’ عشان نجيب الـ value بتاعة كل key.
  2. والطريقة التانية إننا نلف على الـ values على طول، من غير ما نهتم بالـ keys وعلاقتها بالـ values.

ده مثال:

/* declare and initialize the map where the day String value is the key and temperature
  Integer is the value */
Map<String,Integer> mapDaysTemperature = new Map<String,Integer>();
mapDaysTemperature.put('Monday',13);
mapDaysTemperature.put('Tuesday',15); 
mapDaysTemperature.put('Wednesday',30); 

//First loop through the keys 
System.debug('====First loop through the keys Result======');
for(String strDayName : mapDaysTemperature.keySet()){
    //Print the Key and its value
    System.debug('Day: '+strDayName+' temperatire is : '+mapDaysTemperature.get(strDayName));
}

System.debug('====Secong loop through the Values ======');
//Second loop through the values 
for(Integer temperatureValue :  mapDaysTemperature.values()){
    //Print the value
    System.debug('Temperature : '+temperatureValue);
}
صورة من الـ Salesforce Developer Console بتعرض نتيجة الـ loop على الـ keys بتاعة Map وجلب الـ values، وبعدها الـ loop على الـ values وطباعتها
صورة من الـ log في الـ Developer Console.

الخلاصة

فهم الفرق بين الـ Lists والـ Maps والـ Sets حاجة أساسية جداً وإنتو بتعملوا development على Salesforce. الـ collections دي أدوات قوية بتساعدكم تخزنوا الداتا وتتعاملوا معاها وتجيبوها بكفاءة.

اختيار الـ data structure المناسبة للـ use case بتاعكم مهم جداً عشان الكود يبقى كفء ومتظبط. واستخدام data structure غلط ممكن يأثر على جودة الكود والـ performance بتاعه.

الـ Lists هي collections مترتبة ممكن يبقى فيها عناصر متكررة. مفيدة لما تحتاجوا تخزنوا الداتا بترتيب معين وتوصلولها بالـ index. أما الـ Maps فهي collections من key-value pairs بتخليكم توصلوا للداتا بـ key معين، ومثالية للداتا اللي محتاجين ندور فيها كتير. والـ Sets هي collections من عناصر مش متكررة ومش مترتبة، ومفيدة لما تحتاجوا تتابعوا قيم مميزة وتعملوا عمليات الـ set.

ده جدول مقارنة بين الـ Lists والـ Maps والـ Sets في Salesforce:

ListSetMap
الترتيبمترتبةمش مترتبةمش مترتبة
مسموح بالتكرار؟أيوهلأ– الـ Keys: لأ
– الـ Values: أيوه
نجيب العنصر بالـ index؟أيوهلألأ
نجيب العنصر بالـ key؟لأأيوهأيوه
فيها Key-value Pairs؟لألأأيوه
إضافة items جديدةadd methodadd methodput method
الـ Use Cases– collection مترتبة
– الترتيب (Sorting)
– جلب العناصر بالـ index
– تخزين نتيجة SOQL statement (هنشرح الـ SOQL في بوست تاني)
– شيل التكرار
– متابعة مجموعة قيم مميزة لـ field معين، زي set من الـ email addresses المميزة للستة contacts.
– تخزين key-value، زي إننا نخزن الـ account ID كـ key واسم الـ account كـ value.
– البحث السريع بالـ key، زي map فيها أكواد المنتجات وأسعارها.
– الوصول للداتا المرتبطة بكفاءة، زي map فيها الـ contact IDs والـ account IDs بتاعتهم عشان نوصل للـ accounts المرتبطة بسهولة.
جدول مقارنة بين الـ Salesforce Collections: الـ Lists والـ Sets والـ Maps، بيوضح أوجه الشبه والاختلاف.

مصادر مفيدة (Resources)

Join the conversation

لن يتم نشر عنوان بريدك الإلكتروني. الحقول الإلزامية مشار إليها بـ *